//Grabbing with the mouse, and flicking left or right.  
//There is a reasonable feeling of energy being put in to the scroll effort and then slowing to a stop.
// Matthew Joyce




PFont myFont;
int W,H;

int units=365;
int unitsize=50;
int lopx=0;
int hipx=units*unitsize;
int lpos=lopx;


int tick1=unitsize;
int tick2=tick1/2;
int tick3=tick2/12;

int test=200;

kscroll scroller=new kscroll();

event[] arrEvent=new event[test];

void setup() {
  size(600,300);
  W=width;
  H=height;
  smooth();
  frameRate(30);
  colorMode(RGB,255,255,255,100);
  //noLoop();
  stroke(100);
  myFont = createFont("illume_illume_LiberationSans-Regular.ttf", 16);
  textFont(myFont);

  gen_random_events(test);

  }//setup()

  void draw() {
    background(0);
    draw_scale();

    lpos=constrain(lpos-int(scroller.slowdown()),lopx,hipx-W);

    for(int i=0; i<test; i++)
    {
      event e=arrEvent[i];
      e.draw(lpos);
    }
  }//draw()

void draw_scale()
{
  stroke(255);
  fill(100);
  line(0,H/2,W,H/2);
  
  for(int i=lpos; i<lpos+W; i++)
  {
    float x=i-lpos;
    if(i % tick1==0) {
      stroke(200);
      line(x,H/2+15,x,H/2-15); 
      text(i/tick1+1, x, H/2-20);
    } else if(i % tick2==0) {
      stroke(200);
      line(x,H/2+10,x,H/2-10); 
    }
  }
}//draw_scale


void mouseDragged() 
{
  scroller.begin(mouseX);
  lpos=constrain(lpos-int(scroller.speed),lopx,hipx-W);
}//mouseDragged

void mousePressed() 
{
  scroller.grab(mouseX);
}//mousePressed

void mouseReleased() 
{
  scroller.startslowdown();
}//mouseReleased